# 有没有什么方法可以在Edge地址栏输入的网址直接在新标签页打开？

**URL:** <https://meta.appinn.net/t/topic/57502>\
**Category:** 问题求助\
**Tags:** edge\
**Created:** [2024 年6 月 10 日 11:44 UTC](https://meta.appinn.net/t/topic/57502 "2024-06-10T11:44:29Z")\
**Posts on this page:** 18\
**Page:** 1

<div class="post-metadata">

作者： ![corin](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/c/6de8d8/32.png) [@corin](https://meta.appinn.net/u/corin)\
发布日期： [2024 年6 月 10 日 11:44 UTC](https://meta.appinn.net/t/topic/57502/1 "2024-06-10T11:44:29Z")

</div>

常见的国产浏览器基本上都支持的两个功能，一个是双击标签关闭，一个是地址栏打开新标签，我以前不愿意转到edge主要就是这两个问题  
现在看了下，最新版的edge已经支持双击标签关闭了，但地址栏新标签这个仍然没有解决，而且也没有查到有插件之类的方式可以解决，chrome还可以用chrome++来实现，edge好像也不行，大家有好的解决办法吗？

---

<div class="post-metadata">

作者： ![818ba4071bc8](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/8/a88e4f/32.png) [@818ba4071bc8](https://meta.appinn.net/u/818ba4071bc8)\
发布日期： [2024 年6 月 10 日 11:54 UTC](https://meta.appinn.net/t/topic/57502/2 "2024-06-10T11:54:47Z")

</div>

没有使用过 Edge ，但是在 Firefox 和 Chrome 中，直接按 Alt-Enter 就是在新标签页打开链接了，你可以试一下

---

<div class="post-metadata">

作者： ![corin](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/c/6de8d8/32.png) [@corin](https://meta.appinn.net/u/corin)\
发布日期： [2024 年6 月 10 日 11:56 UTC](https://meta.appinn.net/t/topic/57502/3 "2024-06-10T11:56:36Z")

</div>

edge默认是用shift+enter，但我希望能够直接enter就在新标签栏打开，或者至少给我一个可以选择的选项

---

<div class="post-metadata">

作者： ![818ba4071bc8](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/8/a88e4f/32.png) [@818ba4071bc8](https://meta.appinn.net/u/818ba4071bc8)\
发布日期： [2024 年6 月 10 日 12:35 UTC](https://meta.appinn.net/t/topic/57502/4 "2024-06-10T12:35:35Z")

</div>

这样呀，那我就不清楚了，我好像都是使用默认的快捷键，从没改动的想法 :joy:

---

<div class="post-metadata">

作者： ![Lin-arm](https://meta-edge.appinn.com/user_avatar/meta.appinn.net/lin-arm/32/57546_2.png) [@Lin-arm](https://meta.appinn.net/u/Lin-arm)\
发布日期： [2024 年6 月 17 日 11:02 UTC](https://meta.appinn.net/t/topic/57502/5 "2024-06-17T11:02:27Z")

</div>

Edge那么多快捷键不用吗？  
`Win + W`键关闭当前标签页  
`Win + T`键新建标签页  
`Win + R`键刷新当前标签页  
`Ctrl + Shift + S`键来可以截整个网页的屏

具体参考 [Microsoft Edge 中的键盘快捷方式 - Microsoft 支持](https://support.microsoft.com/zh-cn/microsoft-edge/microsoft-edge-%E4%B8%AD%E7%9A%84%E9%94%AE%E7%9B%98%E5%BF%AB%E6%8D%B7%E6%96%B9%E5%BC%8F-50d3edab-30d9-c7e4-21ce-37fe2713cfad)

---

<div class="post-metadata">

作者： ![wankkoree](https://meta-edge.appinn.com/user_avatar/meta.appinn.net/wankkoree/32/19671_2.png) [@wankkoree](https://meta.appinn.net/u/wankkoree)\
发布日期： [2024 年6 月 17 日 11:14 UTC](https://meta.appinn.net/t/topic/57502/6 "2024-06-17T11:14:35Z")

</div>

Edge Alt+Enter 是新标签页打开，Shift+Enter 是新窗口打开。

但是想做到 Enter 默认新标签页打开那就知识盲区了。

---

<div class="post-metadata">

作者： ![corin](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/c/6de8d8/32.png) [@corin](https://meta.appinn.net/u/corin)\
发布日期： [2024 年6 月 19 日 00:45 UTC](https://meta.appinn.net/t/topic/57502/7 "2024-06-19T00:45:05Z")

</div>

就是因为不想改变使用习惯啊

---

<div class="post-metadata">

作者： ![dog](https://meta-edge.appinn.com/user_avatar/meta.appinn.net/dog/32/18667_2.png) [@dog](https://meta.appinn.net/u/dog)\
发布日期： [2024 年6 月 19 日 01:52 UTC](https://meta.appinn.net/t/topic/57502/8 "2024-06-19T01:52:27Z")

</div>

我觉得可以用这个autohotkey脚本进行一定的修改来实现：

考虑到一般而言，在浏览器里按下{enter}键，基本上都是在编辑框中。  
因此，只需要在按下{enter}时，获取当前 “编辑光标” 的坐标位置，进行判定，  
如果编辑光标的位置处于地址栏处，则拦截{enter}改为发送Alt+Enter，否则还是发送{enter}

```auto
#Persistent
SetTimer,GetC,200
Return

GetC:
   if !GetCaretPos(x, y)
      ToolTip, Cant recognize caret position
   else {
      CoordMode, Mouse
      tooltip,% x " " y
   }
   Return

GetCaretPos(ByRef x, ByRef y) {
   static OBJID_CARET := 0xFFFFFFF8
   CoordMode, Caret
   if (A_CaretX != "" && A_CaretY != "")
      x := A_CaretX, y := A_CaretY
   else {
      AccObject := AccObjectFromWindow(WinExist("A"), OBJID_CARET)
      Pos := AccLocation(AccObject)
      x := Pos.x, y := Pos.y
   }
   Return x && y
}

AccObjectFromWindow(hWnd, idObject = 0) {
   static IID_IDispatch := "{00020400-0000-0000-C000-000000000046}"
        , IID_IAccessible := "{618736E0-3C3D-11CF-810C-00AA00389B71}"
        , OBJID_NATIVEOM := 0xFFFFFFF0, VT_DISPATCH := 9, F_OWNVALUE := 1
        , h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
        
   VarSetCapacity(IID, 16), idObject &= 0xFFFFFFFF, AccObject := 0
   DllCall("ole32\CLSIDFromString", "Str", idObject = OBJID_NATIVEOM ? IID_IDispatch : IID_IAccessible, "Ptr", &IID)
   if DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject, "Ptr", &IID, "PtrP", pAcc) = 0
      AccObject := ComObject(VT_DISPATCH, pAcc, F_OWNVALUE)
   Return AccObject
}

AccLocation(Acc, ChildId := 0, ByRef Position := "") {
   static type := (VT_BYREF := 0x4000) | (VT_I4 := 3)
   try Acc.accLocation( ComObject(type, &x := 0), ComObject(type, &y := 0)
                      , ComObject(type, &w := 0), ComObject(type, &h := 0), ChildId )
   catch
      Return
   _x := NumGet(x, "int"), _y := NumGet(y, "int"), _w = NumGet(w, "int"), _h := NumGet(h, "int")
   Position := "x" . _x . " y" . _y . " w" . _w . " h" . _h
   Return {x: _x, y: _y, w: _w, h: _h}
}

```

---

<div class="post-metadata">

作者： ![hzhbest](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/h/e9a140/32.png) [@hzhbest](https://meta.appinn.net/u/hzhbest)\
发布日期： [2024 年6 月 26 日 02:13 UTC](https://meta.appinn.net/t/topic/57502/9 "2024-06-26T02:13:17Z")

</div>

> [@corin](#):
>
> 至少给我一个可以选择的选项

我非得用 Edoge 的时候，就记住新建了标签页再在地址栏输入，要么鼠标点，要么 Ctrl - T 再 Alt - D ……  
反正既然 Edge 不给我选择，我也不选择 Edge 。  
——  
说句暴论，我觉得“地址栏输入后要组合键而不是一键在新标签页打开”这种强制设计，就是PUA使用者，“要么给我多花点时间按快捷键，要么忘掉刚刚的页面，这样我就不用费心思去优化内存占用，还可以把那不知好歹的Firefox羞辱一通！”

---

<div class="post-metadata">

作者： ![dog](https://meta-edge.appinn.com/user_avatar/meta.appinn.net/dog/32/18667_2.png) [@dog](https://meta.appinn.net/u/dog)\
发布日期： [2024 年6 月 26 日 03:00 UTC](https://meta.appinn.net/t/topic/57502/10 "2024-06-26T03:00:35Z")

</div>

搞定！运行exe或ahk即可。

下载地址：

[dogbean.ysepan.com](http://dogbean.ysepan.com/)

 ![Snipper - Snipaste_2024-06-26_11-00-06](https://meta.appinn.net/uploads/default/original/3X/2/6/2626fcf4b6eee0b180e132166310b48fd8926f22.webp)

autohotkey代码：

```auto
#Persistent

; Define global variables
state := 0

; Set a timer to call the getstate function every 100ms
SetTimer, getstate, 100
return

#If state
$enter::
	Send !{enter}
return
#if

getstate:
	if WinActive("ahk_exe msedge.exe")
	{
		if !GetCaretPos(x, y, w, h)
			state:=0
		else {
			WinGetPos,,yy
		  y:=y-yy
			y:=y*(96/A_ScreenDPI)
			if (y < 72)
			state:=1
		}
	}else{
		state:=0
	}
	;ToolTip,% state " " x " " y " " w " " h
return

GetCaretPos(ByRef x, ByRef y, ByRef w, ByRef h) {
	static OBJID_CARET := 0xFFFFFFF8
	CoordMode, Caret
	if (A_CaretX != "" && A_CaretY != "")
		x := A_CaretX, y := A_CaretY
	else {
		AccObject := AccObjectFromWindow(WinExist("A"), OBJID_CARET)
		Pos := AccLocation(AccObject)
		x := Pos.x, y := Pos.y, w := Pos.w ,h:=pos.h
	}
	return x && y && w && h
}

AccObjectFromWindow(hWnd, idObject = 0) {
	static IID_IDispatch := "{00020400-0000-0000-C000-000000000046}"
		, IID_IAccessible := "{618736E0-3C3D-11CF-810C-00AA00389B71}"
		, OBJID_NATIVEOM := 0xFFFFFFF0, VT_DISPATCH := 9, F_OWNVALUE := 1
		, h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")

	VarSetCapacity(IID, 16), idObject &= 0xFFFFFFFF, AccObject := 0
	DllCall("ole32\CLSIDFromString", "Str", idObject = OBJID_NATIVEOM ? IID_IDispatch : IID_IAccessible, "Ptr", &IID)
	if DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject, "Ptr", &IID, "PtrP", pAcc) = 0
		AccObject := ComObject(VT_DISPATCH, pAcc, F_OWNVALUE)
	return AccObject
}

AccLocation(Acc, ChildId := 0, ByRef Position := "") {
	static type := (VT_BYREF := 0x4000) | (VT_I4 := 3)
	try Acc.AccLocation( ComObject(type, &x := 0), ComObject(type, &y := 0)
		, ComObject(type, &w := 0), ComObject(type, &h := 0), ChildId )
	catch
		return
	_x := NumGet(x, "int"), _y := NumGet(y, "int"), _w = NumGet(w, "int"), _h := NumGet(h, "int")
	Position := "x" . _x . " y" . _y . " w" . _w . " h" . _h
	return {x: _x, y: _y, w: _w, h: _h}
}

```

---

<div class="post-metadata">

作者： ![dog](https://meta-edge.appinn.com/user_avatar/meta.appinn.net/dog/32/18667_2.png) [@dog](https://meta.appinn.net/u/dog)\
发布日期： [2024 年6 月 26 日 03:02 UTC](https://meta.appinn.net/t/topic/57502/11 "2024-06-26T03:02:20Z")

</div>

你试试，好用的话，记得点个解决方案哈~

---

<div class="post-metadata">

作者： ![corin](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/c/6de8d8/32.png) [@corin](https://meta.appinn.net/u/corin)\
发布日期： [2024 年11 月 17 日 14:16 UTC](https://meta.appinn.net/t/topic/57502/12 "2024-11-17T14:16:43Z")

</div>

感谢，我尝试一下

---

<div class="post-metadata">

作者： ![xiaokonglong](https://meta-edge.appinn.com/user_avatar/meta.appinn.net/xiaokonglong/32/908_2.png) [@xiaokonglong](https://meta.appinn.net/u/xiaokonglong)\
发布日期： [2024 年11 月 18 日 00:23 UTC](https://meta.appinn.net/t/topic/57502/13 "2024-11-18T00:23:20Z")

</div>

> **[GitHub - yisqiu/edge\_plus: Chromium-based Edge 增强软件](https://github.com/yisqiu/edge_plus)**
>
> Chromium-based Edge 增强软件

- 采用转发中键关闭标签方式，效率更高，保留基本功能，去除冗余功能
- 小键盘回车采用第二搜索引擎（在地址栏中输入关键词，如果直接按小键盘上面的回车键，将采用第二搜索引擎进行搜索，该搜索引擎可以在配置文件中自定义）
- 地址栏全角字符自动转换功能：：转换成: 、转换成/
- 修复垂直标签状态下面当有固定标签时，右击关闭标签功能失效的bug
- 右键标题栏打开新标签
- 地址栏回车新开tab打开网页
- 右键关闭标签页
- 按住右键时滚轮滚动标签栏
- 同时支持Edge（版本 128.0.2739.42 (正式版本) (64 位)）、Chrome（版本 128.0.6613.114（正式版本） （64 位））

---

<div class="post-metadata">

作者： ![PandaFiredoge](https://meta-edge.appinn.com/user_avatar/meta.appinn.net/pandafiredoge/32/58789_2.png) [@PandaFiredoge](https://meta.appinn.net/u/PandaFiredoge)\
发布日期： [2024 年11 月 18 日 13:18 UTC](https://meta.appinn.net/t/topic/57502/14 "2024-11-18T13:18:48Z")

</div>

[RunningCheese Edge 131.0 稳定版 - 奔跑中的奶酪](https://www.runningcheese.com/edge)

> 定制版 Chrome 浏览器默认使用 GreenChrome增强插件，所以书签和链接的默认打开方式修改成了在 **新标签页** 打开。但这有副作用，这导致无法使用书签栏里的“小书签”，需要取消勾选“处理弹出菜单”。

---

<div class="post-metadata">

作者： ![corin](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/c/6de8d8/32.png) [@corin](https://meta.appinn.net/u/corin)\
发布日期： [2024 年11 月 18 日 16:04 UTC](https://meta.appinn.net/t/topic/57502/15 "2024-11-18T16:04:13Z")

</div>

这个似乎不行，它只解决了“书签和链接”，而不是地址栏

---

<div class="post-metadata">

作者： ![corin](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/c/6de8d8/32.png) [@corin](https://meta.appinn.net/u/corin)\
发布日期： [2024 年11 月 18 日 16:04 UTC](https://meta.appinn.net/t/topic/57502/16 "2024-11-18T16:04:38Z")

</div>

兄弟，你这个才是完美解决方案，真心赞美你

---

<div class="post-metadata">

作者： ![africa](https://meta-edge.appinn.com/letter_avatar_proxy/v4/letter/a/3ab097/32.png) [@africa](https://meta.appinn.net/u/africa)\
发布日期： [2024 年12 月 30 日 03:05 UTC](https://meta.appinn.net/t/topic/57502/17 "2024-12-30T03:05:53Z")

</div>

所以我想改成地址栏输入网址就在当前标签页打开怎么改回去呢？我现在就用的奶酪的131，新标签打开太不习惯了

---

<div class="post-metadata">

作者： ![oldsento](https://meta-edge.appinn.com/user_avatar/meta.appinn.net/oldsento/32/58815_2.png) [@oldsento](https://meta.appinn.net/u/oldsento)\
发布日期： [2024 年12 月 30 日 12:29 UTC](https://meta.appinn.net/t/topic/57502/18 "2024-12-30T12:29:16Z")

</div>

对着链接按鼠标中键，