鼠标侧键增强

2021年更新:事实证明,之前功能搞得太复杂根本记不住怎么用。侧键的使用频率反而更低了 :joy:

现在我的开机ahk脚本里只保留了四个跟鼠标相关的功能

; 前进侧键改为Home键

XButton2:: 
MouseGetPos,,,winID
IfWinNotActive, ahk_id %winID%
{
  WinActivate, ahk_id %winID%
}
SendInput, {Home}
return


; 后退侧键改为End键

XButton1:: 
MouseGetPos,,,winID
IfWinNotActive, ahk_id %winID%
{
  WinActivate, ahk_id %winID%
}
SendInput, {End}
return

; 左Win键+鼠标滚轮切换虚拟桌面

<#WheelUp::#^Left
<#WheelDown::#^Right

; 左Alt键+鼠标滚轮切换窗口

<!WheelUp::ShiftAltTab
<!WheelDown::AltTab


2020年原帖这个脚本适合五键以上的鼠标,这种鼠标侧面的第四、第五个按键,使用频率要比常用的左、右、中键低不少

不如重新映射一些功能,抢救一下它们的使用频率吧 :rofl:

XButton1是鼠标上更靠近我们身体的那个侧键,默认功能是浏览器的“后退”

; 单独按仍旧作为“后退”
XButton1:: Browser_Back

; 组合右键作为“前进”
XButton1 & RButton:: Browser_Forward

; 组合左键在资源管理器中返回上级目录
XButton1 & LButton:: !Up

; 组合中键关闭标签页
XButton1 & MButton:: ^w

; 组合滚轮切换标签页

; 默认切换方式
; 在Chrome、OneNote、Excel、Brackets中验证有效
; 在文本编辑软件中不会误输入Tab
XButton1 & WheelUp:: ^PgUp
XButton1 & WheelDown:: ^PgDn

/* 替代切换方式,注释上段并取消注释本段以启用
; 在Chrome、旧版Edge、Affinity Photo中验证有效
; 在记事本、Word等部分文本编辑软件中使用会导致输入Tab
XButton1 & WheelUp:: ^+Tab
XButton1 & WheelDown:: ^Tab
*/

XButton2是更靠近屏幕的那个侧键,默认功能是浏览器的“前进”。Windows自带的触摸板三指左右滑动切换窗口的手势灵敏度太高,很难准确地停留在想要选中的窗口,另外触摸板也不是所有电脑都有的硬件,那么就给XButton2安排一些用于切换窗口的功能好了

; 直接按调出Alt+Tab菜单
XButton2:: AltTabMenu

; 组合滚轮在各个窗口中轮选
XButton2 & WheelDown:: AltTab
XButton2 & WheelUp:: ShiftAltTab

; 组合中键取消轮选
XButton2 & MButton:: Escape

; 组合左右键在虚拟桌面之间切换
XButton2 & LButton:: #^Left
XButton2 & RButton:: #^Right
通俗易懂的AutoHotkey脚本使用方法
  1. 安装AutoHotkey

  2. 新建一个.ahk后缀的文件

  3. 用记事本打开这个.ahk文件

  4. 粘贴脚本

  5. 保存,然后把.ahk文件复制到

    C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
    
2 Likes

请教一下,文章中如“2020年原贴”前的活动三角标志,是怎么制作出来的?

发帖的工具栏有一个齿轮图标,点开有一个隐藏详情

谢谢,又学到了新知识