能给我写个批处理么，点一下就设置ie代理为
127.0.0.1 1080
再点一下就关闭代理
不需要出现选择，后台运行。
网上搜了一下，http://www.guuge.com/post-94.html
大多需要手动选择关闭或者开启代理。
虽然目前在用IEProxyToggle 可以一键开启或者关闭代理，但是这个要事先在IE里设置代理地址。
我在IE 设置127.0.0.1 1080 这个代理地址后，有时候代理地址会消失。
想部分网页走代理，其他的不走，快速切换？
chrome的话可以试试Proxy SwitchyOmega，或者老一点的Proxy SwitchySharp，可以设定策略
羡慕你们 IE 用户，不是很懂
我觉得 AHK 肯定可以搞定，但是我不会……
firefox 配合自动扩展pan, 很好很省心.
可以试下用全局代理调度软件（不是浏览器代理调度插件）
根据访问的目标自动分配路线（直连/代理）
像是其中Privoxy和Proxomitron，功能有：
- 全局广告拦截(网页、软件)
- 跨浏览器插JS
- 自定义跳转
- 修改http头
- …
单说自定义跳转：
可以做家长控制，
可以做个人专用的跨浏览器网址缩写，
可以改Win10小娜的搜索引擎，
可以自设本地前端公共库（如Google字体库和JS公共库）
1 个赞
以前GoAgent时代，写的批处理。很久不用了：
设置IE Goagent代理.bat
@echo off
title 自动设置代理服务器
echo 正在设置代理服务器……
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "127.0.0.1:8087" /f
echo 设置完毕
取消IE Goagent代理.bat
@echo off
title 自动设置代理服务器 没有代理
echo 正在清空代理服务器设置……
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "" /f
echo 代理服务器设置已经清空
echo 设置完毕
1 个赞
为啥没人说shadowsocks。其实它的代理切换功能蛮全的。。。
在高人的帮助下，搞定了 http://www.guuge.com/post-94.html#comment-20
@echo off
cacls.exe "%SystemDrive%\System Volume Information" >nul 2>nul
if %errorlevel%==0 goto Admin
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
echo Set RequestUAC = CreateObject^("Shell.Application"^)>"%temp%\getadmin.vbs"
echo RequestUAC.ShellExecute "%~s0","","","runas",1 >>"%temp%\getadmin.vbs"
echo WScript.Quit >>"%temp%\getadmin.vbs"
"%temp%\getadmin.vbs" /f
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
exit
:Admin
@echo off
setlocal
set key="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
set value=ProxyEnable
for /f "tokens=2* skip=2" %%a in ('reg query %key% /v %value%') do (
set data=%%b
)
set /a newdata=1-data
reg add %key% /v %value% /t REG_DWORD /d %newdata% /f >nul
if %newdata%==1 reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /t REG_SZ /d 127.0.0.1:1080 /f >nul && echo 已经开启全局代理，并将代理服务器设置为127.0.0.1:1080
if %newdata%==0 (
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v "ProxyServer" /f >nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /t REG_SZ /d /f >nul
echo 已经关闭代理，并将代理服务器设置为默认值
)
goto :eof
1 个赞
翻出个旧脚本，这个相对简洁点，可以试试
@echo off
title IE Proxy Toggle
for /f "tokens=3" %%i in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v "ProxyEnable"') do set state=%%i
goto %state%
:0x1
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v "ProxyEnable" /t REG_DWORD /d 0 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "" /f
cls & echo 已关闭IE代理，按任意键退出
pause
exit
:0x0
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "127.0.0.1:8080" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v "ProxyEnable" /t REG_DWORD /d 1 /f
cls & echo 已开启IE代理，按任意键退出
pause
exit
补充：
如果需要管理员身份运行的话，没必要动态生成VBS来提权的。
给脚本创建一个快捷方式→属性→高级→勾选"用管理员身份运行"→确定。
以后运行这个快捷方式就行了。
1 个赞
Privoxy可以转发socks的
我说的真全局是类似于XXX和虚拟网卡技术，我目前用的是SSTAP
chrome我在用这个，我想切换代理主要还是google earth，因为它是用IE的代理设置。
这种就需要选择啊，我是想运行一下这个批处理就启用代理，再运行一下就关闭代理。
加入个判断，有代理就删除代理，没有代理就启动代理。
ProxyPal 还是需要提前去设置好代理，我是需要运行一下就自动填代理地址 为127.0.0.1 端口为1080的软件。
被你说得很诱人的样子，只不过Privoxy的配置比较难，很多软件是依赖他的，但是单独用就感觉自己在做服务器运维一样。。。另外这应该是HTTP代理，不算真·全局