求一个多平台直播录制软件，支持检测分辨率变化分段的

问题求助
1

如题，求一个多平台直播录制软件，支持检测到直播分辨率变化自动分段的那种，类似B站录播姬，但是他只支持b站直播（:rofl: 目前也只看到他有分辨率变化自动分段修复花屏的功能），直播在PK连线的时候分辨率会变化，然后容易花屏，而且很多播放器在播放可变分辨率的视屏的时候画面容易拉伸变形，目前在用的Bililive-go也不支持快手平台了，心累，所以，特来求一个好用的录播工具，谢谢大家！

2

你可以用别的工具录完之后再拿录播姬去处理，并且录播姬这头他是有提供命令行支持的，可以很容易就实现批量修复。。。

3

:thinking: 我现在就在这么干，不过 不会命令行，就一个个拖进去修复，有一丢丢麻烦。

4

存成bat文件试试，批量修复文件夹内所有的flv文件。

@echo off
setlocal enabledelayedexpansion

:: 配置参数 - 这里默认Cli.exe、bat文件、需要修复的视频文件都在同一个文件夹内，不然需要改路径，路径需要加双引号。
set RECORDER_CLI=BililiveRecorder.Cli.exe
set ROOT_DIR=.

echo 开始扫描FLV文件...

set file_count=0
for /r "%ROOT_DIR%" %%f in (*.flv) do (
    set /a file_count+=1
    echo 找到了: %%f
)

if %file_count%==0 (
    echo 未找到任何FLV文件
    pause
    exit /b
)

echo 共找到 %file_count% 个FLV文件
set /p confirm=是否开始批量修复？(y/n): 
if /i not "%confirm%"=="y" (
    echo 已取消
    pause
    exit /b
)

set success_count=0
set failed_count=0

for /r "%ROOT_DIR%" %%f in (*.flv) do (
    echo 正在修复: %%f
    
    :: 输出路径
    set "input_path=%%f"
    set "output_dir=%%~dpf"
    set "filename=%%~nf"
    set "output_base=!output_dir!!filename!_fixed.flv"
    
    :: 执行修复
    "%RECORDER_CLI%" tool fix "!input_path!" "!output_base!"
    
    if !errorlevel!==0 (
        echo 修复成功: !input_path!
        set /a success_count+=1
    ) else (
        echo 修复失败: !input_path!
        set /a failed_count+=1
    )
)

echo.
echo 修复完成！
echo 成功: %success_count% 个文件
echo 失败: %failed_count% 个文件
pause
5

感谢:folded_hands:t2:，试过了，完全可以，要是能加个修复后删除源文件就更好了 :see_no_evil_monkey:

6

饿，这个风险有点大，毕竟返回成功修复完毕，不代表真的修好了。

1 个赞