Poerin 的软件目录

讨论分享
1

我的空间

2

以前试过Feep
因为没有内置操作提示就删掉了。

我没法一次过记住所有操作方式， 试用时要不停去瞄简介.txt。
假如当作默认看图软件，说不定搁十天半月又得去找简介.txt。
烦，删……

强烈建议加上操作提示，样式见小众论坛的提示（键盘？号 Shift+/）
额外建议：无背景、细边框/无边框。（类似image eye）

5

在 Windows 10 中使用 AutoHotkey 替代 iKey 和 WinKeyPlus 的方案：

#NoEnv
SendMode Input
SetWorkingDir %A_ScriptDir%


VarSetCapacity(rectWorkingArea, 16)
VarSetCapacity(rectScreen, 16)
NumPut(A_ScreenWidth, rectScreen, 8, "Int")
NumPut(A_ScreenHeight, rectScreen, 12, "Int")
DllCall("User32\SystemParametersInfo", Int, 48, Int, 0, Ptr, &rectWorkingArea, Int, 1)

; Win+A，隐藏/显示任务栏
#a::
IfWinNotExist, ahk_class Shell_TrayWnd
{
    WinShow ahk_class Shell_TrayWnd
    DllCall("User32\SystemParametersInfo", Int, 47, Int, 0, Ptr, &rectWorkingArea, Int, 1)
}
else
{
    WinHide ahk_class Shell_TrayWnd
    DllCall("User32\SystemParametersInfo", Int, 47, Int, 0, Ptr, &rectScreen, Int, 1)
}
return

; Win+C，计算器
#c::
Run, C:\Windows\system32\calc.exe
return

; Win+V，记事本
#v::
Run, C:\Windows\system32\notepad.exe
return

; Win+F，Everything
#f::
Run, C:\Program Files\Everything\Everything.exe
return

; Win+W，交换鼠标左右键
#w::
if (DllCall("User32\GetSystemMetrics", Int, 23))
{
    DllCall("User32\SwapMouseButton", Int, 0)
}
else
{
    DllCall("User32\SwapMouseButton", Int, 1)
}
return

; Win+H，关闭显示器
#h::
DllCall("User32\SendMessage", Ptr, 0xFFFF, Int, 0x0112, Int, 0xF170, Int, 2)
return


; Win+Esc | Alt+Backspace，关闭窗口
#Esc::
!Backspace::
if (!(WinActive("Program Manager")))
{
    WinExist("A")
    PostMessage, 0x112, 0xF060
}
return

; Win+F1 | Alt+N，最小化
#F1::
!-::
if (!(WinActive("Program Manager")))
{
    WinExist("A")
    PostMessage, 0x112, 0xF020
}
return

; Win+F2 | Alt+M，最大化/恢复
#F2::
!=::
if (!(WinActive("Program Manager")))
{
    if (DllCall("User32\IsZoomed", Ptr, WinExist("A")))
    {
        PostMessage, 0x112, 0xF120
    }
    else
    {
        PostMessage, 0x112, 0xF030
    }
}
return


; Ctrl+PageUp，撤销
^PgUp::^z
return

; Ctrl+PageDown，重做
^PgDn::^y
return

; Ctrl+Insert，复制
^Insert::^c
return

; Ctrl+Delete，剪切
^Delete::^x
return

; Ctrl+Home，粘贴
^Home::^v
return

; Ctrl+End，全选
^End::^a
return

; Laufe
^PrintScreen::
XButton1::
Send #{vkC0}
return

; 任务视图
XButton2::^!Tab
return
4

在你的主页留言完全没反应，我想问Feep在我win7和win10上都不显示是为什么，难道启动就直接崩溃退出了？还有WinKeyPlus的网盘链接为何删除了？ @Poerin

3

不想把提示写在程序里（你看我路径都不想显示在界面上:joy:），键盘操作会用方向键和空格就是最基本的功能了，组合快捷键主要就那三四个，Ctrl+A复制路径，Ctrl+B显示文件，Ctrl+C复制图像，Shift+Delete删除，没了。如果只是看图基本也用不到的。

好像本来就没有边框呀…背景色还是要有的，那个是存放图片的容器呀，关系到调整图片大小的逻辑，如果改了那就不是 Feep 了。